; Install-AmigaPlayer - installer script for AmigaPlayer 3.0
;
; For unattended use set the environment variable AP_INSTALL_DEST to the target
; drawer before starting Installer (the AmigaPlayer drawer is created inside it).

(set @app-name "AmigaPlayer 3.0")
(set @default-dest "SYS:Utilities")
(set srcdir (tackon (pathonly @icon) "AmigaPlayer"))
(set envdir (getenv "AP_INSTALL_DEST"))

(if (= envdir "")
  (
    (welcome "Instalacja AmigaPlayer 3.0")
    (message "AmigaPlayer to odtwarzacz muzyki modulowej (MOD, S3M, XM, IT, MED, SAP, SID, AHX/HVL, FC).\n\nInstalator utworzy szuflade AmigaPlayer w wybranym miejscu.")
    (set instdir
      (askdir
        (prompt "Gdzie zainstalowac AmigaPlayer? Szuflada AmigaPlayer zostanie utworzona w wybranym miejscu.")
        (help "Wybierz szuflade, w ktorej ma powstac szuflada AmigaPlayer. Mozesz ja potem przeniesc w dowolne miejsce.")
        (default @default-dest)
      )
    )
  )
  (set instdir envdir)
)

(set instdir (tackon instdir "AmigaPlayer"))

(makedir instdir (infos))

(copyfiles
  (prompt "Kopiowanie programu, ikony, dokumentacji i licencji")
  (help @copyfiles-help)
  (source srcdir)
  (dest instdir)
  (all)
)

(if (= envdir "")
  (
    (if (exists "LIBS:muimaster.library")
      (set note "Znaleziono MUI: program uruchomi sie z interfejsem MUI.")
      (set note "Nie znaleziono MUI (muimaster.library): program uruchomi klasyczny interfejs. Zainstaluj MUI, aby uzyc interfejsu MUI.")
    )
    (exit (cat "AmigaPlayer zostal zainstalowany w:\n" instdir "\n\n" note "\n\nPrzewodnik: AmigaPlayer.guide"))
  )
  (exit (quiet))
)
